The Harmonic rays theorem.

Theorem (harmonic rays) : Let ABCD be a quadrilateral. Let F be the point of intersection of with and let G be the point of intersection of with . One of both of the points F and G may be on the line at infinity. Let be the line through A parallel to and let M be the intersection of the diagonals of ABCD. If meets at P and meets at Q then the line segments PQ and QA are congruent.

A diagram

> a1 =0: a2 =0:

> b1:=-6: b2:=-3/2:

> c1:=-4: c2:=-9:

> d1:=3: d2:=-3:

> geometry[point](A,[a1,a2]):
geometry[point](B,[b1,b2]):
geometry[point](C,[c1,c2]):
geometry[point](D,[d1,d2]):

> geometry[segment](AB,[A,B]):
geometry[segment](AC,[A,C]):
geometry[segment](BC,[B,C]):
geometry[segment](CD,[C,D]):
geometry[segment](AD,[A,D]):
geometry[line](lineAD,[A,D]):
geometry[segment](BD,[B,D]):

> geometry[line](lineCD,[C,D]):

> geometry[line](lineBC,[B,C]):

> geometry[line](lineAD,[A,D]):

> geometry[line](lineBD,[B,D]):

> geometry[line](lineAC,[A,C]):
geometry[line](lineAB,[A,B]):

> geometry[intersection](F, lineBC,lineAD):

> geometry[intersection](M, lineBD,lineAC):

> geometry[intersection](G, lineAB,lineCD):

> geometry[line](lineFM,[F,M]):

> geometry[line](lineGM,[G,M]):
geometry[line](vanishingline,[F,G]):

> axis:='axis':geometry[ParallelLine](axis,A,vanishingline):

> T:='T':geometry[intersection](T, lineBD,axis):

> Q:='Q': geometry[intersection](Q, lineFM,axis):

> R:='R':geometry[intersection](R, lineGM, axis):

> geometry[intersection](P, axis,lineBC):

> harmonicdiagram:={axis(color=tan, thickness=2), vanishingline(color=tan, thickness=2), P,Q,A, lineAD(color=blue), AC(color=red), BD(color=red),F,G,lineAB(color=blue),lineCD(color=blue),BC(color=blue,thickness=3),B,C,D,M,lineBC(color=blue),AD(color=blue,thickness=3),CD(color=blue,thickness=3),AB(color=blue,thickness=3), lineFM(color=green)}:

PROOF

First we draw the diagram. When F or G is at infinity then ABCD has at least one pair of parallel sides. We leave it as exercises to handle theses very intersting cases.

> geometry[draw](harmonicdiagram,scaling=constrained);

There is no loss in assuming that the point A is at the origin [0,0] and that B is [1,0] as this is a matter of choice of coordinates and scale, neither of which affects this problem. We use the notation Apt, Bpt, .. etc. to indicate points and to avoid conflict some Maple reserved symbols (e.g. "D" and "O").

> restart;

> Apt:=[0,0]:Bpt:=[1,0]: Cpt:=[c1,c2]:Dpt:=[d1,d2];

The theorem is all about points of intersection of lines so we provide a word which calculates points of intersection of pairs of lines described by points on them. "intsect(Apt,Bpt,Cpt,Dpt)" is the point of intersection of the line through Apt and Bpt with the one through Cpt and Dpt

> intsect:=proc(Apt,Bpt,Cpt,Dpt) local s,t ,L1,L2,ANS,EQ:
L1:=Apt+t*(Bpt-Apt):
L2:=Cpt+s*(Dpt-Cpt):
EQ:=expand(L1-L2):
ANS:=solve({EQ[1]=0,EQ[2]=0},{s,t}):
simplify(expand(subs(ANS,L1))) end:

> Mpt:=intsect(Apt,Cpt,Bpt,Dpt);

Now calculate F and G, the points of intersection of opposite sides

> Fpt:=intsect(Bpt,Cpt,Dpt,Apt);

> Gpt:=intsect(Apt,Bpt,Cpt,Dpt);

The line parallel to the line through F and G which passes through A has parametric form A+t(F -G). With t=1 we have a point other than A on this line

> Tpt:=Apt+(Fpt-Gpt);

Now we calculate P and Q, the points of intersection of this parallel with the lines BC and MF

> Ppt:=intsect(Bpt,Cpt,Apt,Tpt);

> Qpt:=intsect(Mpt,Fpt,Apt,Tpt);

The theorem says that the distance from P to Q is equal to the distance from Q to A. Since we have set A to be the origin this is equivalent to saying that the distance from P to the origin is twice the distance from Q to the origin which is equivalent to "ratsq" the ratio of the squares being 4.

> ratsq:=(Ppt[1]^2+Ppt[2]^2)/(Qpt[1]^2+Qpt[2]^2);

> simplify(expand(ratsq));

This completes the proof.

EXERCISES

EXERCISE: Explain why statement of the harmonic ray theorem if F and G are points at infinity the theorem should be interpreted as assuming that the quadrilateral is a rectangle. Prove the theoem in this case (Maple is not required)

EXERCISE: Interpret the harmonic ray theorem when G is a point at infinity and F is not. Prove the theorem in this case (Maple is not required)

EXERCISE: Check the necessity of the hypothesis that L be parallel to the line FG by doing the calculations for the harmonic ray theorem in a case when L is not parallel to the line FG.