#atom - Ri R^i RI R^I Li LI M H ~N Ch ~n T Th D Dh N Sh.
#vars $abc: Ri RI Li LI M H ~N Ch ~n T Th D Dh N Sh a b bh c ch
d dh e g gh h i j jh k kh l m n o p ph r s sh t th u v y ;.
#vars $obstruent: - b bh c ch d dh g gh h j jh k kh l p ph s
sh t th Ch T Th D Dh Sh.
#vars $consonant: - b bh c ch d dh g gh h j jh k kh l m n p ph r s
sh t th v y ~N Ch ~n T Th D Dh N Sh.
#vars $consonant2: - b bh c ch d dh g gh h j jh k kh l m n p ph r
s sh t th v y ~N Ch ~n T Th D Dh N Sh.
#vars $pal: ch Ch j jh sh ~n y.
#vars $nonpal: b bh d dh D Dh g gh h k kh l m n ~N N p ph r s Sh t
th T Th v. 
#vars $coronalconsonant: ch Ch j jh ~n T Th D Dh N t th d dh n sh
s.
#vars $retroflexcontinuant: r Ri RI Sh.
#vars $vowel2: a e i o u Ri.
#vars $nonivowel: a e o u Ri.
#vars $nonuvowel: a e i o Ri.
#vars $ruki: r Ri o u k e i.
#vars $vowel: a e i o u Ri.
#vars $vowelplus: a e i o u Ri n m y v.
#vars $offon: retron retroff.
#vars $nonneut: masc fem.
#vars $part: stem suff.
#vars $gender: masc fem neut.
#vars $number: sg du pl.

SANDHI:
    <$offon> ==
    <$offon -> ==
    <$offon $consonant $consonant2 $obstruent -> == <$offon
$consonant ->
    <$offon $consonant $obstruent -> == <$offon $consonant ->
    <$offon $nonpal -> == $nonpal
    <$offon $pal -> == k
    <$offon $consonant n $consonant2> == <$offon $consonant a
$consonant2> 
    <$offon $pal s> == <$offon k s>
    <$offon $abc> == $abc <$offon>
    <$offon a s bh> == o <$offon bh>
    <$offon $pal bh> == g <$offon bh>
    <$offon j n> == <retroff j ~n>
    <$offon t bh> == d <retroff bh>
    <$offon $ruki s $vowel> == <$offon $ruki Sh $vowel>
    <$offon $vowel ;> == <$offon $vowel $vowel>
    <$offon r ;> == <$offon RI>
    <$offon Ri Ri> == <$offon RI>
    <$offon Ri> == R^i <$offon>
    <$offon RI> == R^I <$offon>
    <$offon $consonant r $consonant2> == <$offon $consonant Ri
$consonant2>
    <$offon $vowel $vowel $vowel2> == <$offon $vowel $vowel2>
    <$offon $consonant a i i> == <$offon $consonant a i>
    <$offon $consonant a i> == <$offon $consonant e>
    <$offon M t> == n <retroff t>
    <$offon a e> == <$offon a i>
    <retroff $retroflexcontinuant> == <retron $retroflexcontinuant>
    <$offon i $nonivowel> == y <$offon $nonivowel>
    <$offon u $nonuvowel> == v <$offon $nonuvowel>
    <$offon a y $consonant> == <$offon e $consonant>
    <$offon a v $consonant> == <$offon o $consonant>
    <$offon i y $consonant> == <$offon i i $consonant>
    <$offon u v $consonant> == <$offon u u $consonant>
    <retron n $vowelplus> == <retroff N $vowelplus>
    <retron $coronalconsonant> == <retroff $coronalconsonant>.

ALL_STEM:
    <astem> == "<root>" a
    <istem> == "<root>" i
    <ustem> == "<root>" u
    <nstem> == "<vstem>" n 
    <strongstem> == <gunastem>
    <smstem> == "<vstem>" s m
    <longvstem> == "<vstem>" ; 
    <longnstem> == "<longvstem>" n
    <stem> == "<vstem>"
    <suff> == 
    <> == SANDHI:<retroff "<"<gen>" stem>" "<"<gen>" suff>" -> 
    <masc> == "<>"
    <neut> == "<>"
    <fem> == "<>"
    <suff sg dir nom> == s
    <suff sg dir acc> == m
    <suff sg obl dat> == e
    <suff sg obl ins> == a a
    <suff sg obl gen> == a s
    <suff sg obl loc> == i
    <suff du dir> == a u
    <suff du obl> == bh y a a m
    <suff du obl gen> == o s
    <du obl loc> == <du obl gen>
    <suff pl obl dat> == bh y a s
    <suff pl obl ins> == bh i s
    <suff pl obl gen> == a a m
    <suff pl obl loc> == s u
    <$gender $part sg obl abl> == "<$gender $part sg obl gen>"
    <suff pl dir> == a s
    <pl obl abl> == "<pl obl dat>"
    <stemres> ==
    <stemobs> ==
    <gunastem> == "<astem>" "<stemres>" "<stemobs>"
    <vrddhistem> == <longvstem> "<stemres>" "<stemobs>"
    <neut suff sg dir> ==
    <neut suff du dir> == i i
    <neut suff pl dir> == i
    <$gender $part $number dir voc> == "<$gender $part $number dir
nom>".

V_STEM:
    <> == ALL_STEM
    <fem suff pl dir acc> == s
    <stem pl obl gen> == "<longnstem pl obl gen>"
    <suff pl dir acc> == n
    <stem pl dir acc> == "<longvstem pl dir acc>"
    <neut stem pl dir> == <longnstem>
    <fem suff sg obl loc> == a m
    <$gender suff sg dir voc> == .

IU_STEM: 
    <> == V_STEM
    <stem du dir> == <longvstem>
    <suff du dir> ==
    <neut stem du dir> == <nstem>
    <neut stem du obl gen> == <nstem>
    <masc stem sg obl ins> == <nstem>
    <fem stem sg obl ins> == <vstem>
    <stem pl dir nom> == "<strongstem>"
    <stem sg obl> == "<strongstem>"
    <stem sg obl loc> == "<root>"
    <$nonneut suff sg obl gen> == s
    <$nonneut suff sg obl loc> == a u
    <neut stem sg obl> == <nstem>
    <$nonneut stem sg dir voc> == <gunastem>.

A_STEM: 
    <> == V_STEM
    <vstem> == <astem>
    <estem> == "<root>" e
    <stem sg obl ins> == <estem>
    <stem du obl> == <longvstem>
    <stem du obl gen> == "<stem>" y
    <stem pl dir nom> == <vstem>
    <stem pl obl dat> == <estem>
    <stem pl obl loc> == <estem>
    <$gender suff sg obl abl> == a a t
    <suff sg obl gen> == s y a
    <suff sg obl ins> == n a
    <suff pl obl ins> == e s.

VV_STEM:
    <> == V_STEM
    <vstem> == "<root>" "<stemvowel>" ;
    <$gender stem sg dir voc> == "<root>" "<stemvowel>"
    <gen> == fem
    <stem sg obl> == "<stem>" "<stemres>" a
    <longvstem> == "<vstem>".

VV_STEM2:
    <> == VV_STEM
    <suff sg dir nom> ==.

AA_STEM:
    <> == VV_STEM2
    <vstem> == "<root>" ;
    <stemres> == y
    <stem du dir> == "<root>"
    <stem sg obl ins> == "<root>" <stemres>
    <stem du obl gen> == <stem sg obl ins>
    <suff du dir> == i
    <$gender stem sg dir voc> == "<root>"
    <$gender suff sg dir voc> == i.

II_STEM:
    <> == VV_STEM2
    <stemvowel> == i.

MS_STEM:
    <> == C_STEM
    <stem> == "<root>".

UU_STEM:
    <> == VV_STEM
    <stemvowel> == u.

NONPRON_A_STEM:
    <> == A_STEM
    <stem sg obl abl> == ALL_STEM
    <suff sg obl dat> == a y a
    <neut suff sg dir> == <suff sg dir acc>
    <neut suff sg dir voc> == <suff sg dir voc>.

PRON_A_STEM:
    <> == A_STEM
    <neut suff sg dir> == t 
    <stem sg obl loc> == <smstem>
    <$gender stem sg obl abl> == <smstem>
    <stem sg obl dat> == <smstem> a
    <suff sg obl loc> == i n
    <stem pl obl gen> == "<stem pl dir nom>" s
    <suff pl dir nom> == 
    <stem pl dir nom> == <estem>
    <$number dir voc> == doesn't exist.

I_STEM:
    <> == IU_STEM
    <vstem> == <istem>
    <stemres> == y.

U_STEM:
    <> == IU_STEM
    <vstem> == <ustem>
    <stemres> == v.

C_STEM:
    <> == ALL_STEM
    <vstem> == <astem>
    <stem> == "<vstem>" "<stemobs>"
    <suff sg dir acc> == a ALL_STEM
    <neut stem pl dir> == "<longvstem>" M "<stemobs>".

DERC_STEM:
    <> == C_STEM
    <stem> == "<weakeststem>"
    <masc stem sg dir nom> == <longvstem>
    <masc suff sg dir nom> ==
    <weakeststem> == "<root>" "<stemres>" "<stemobs>"
    <strongstem> == "<vrddhistem>"
    <stem pl obl> == "<middlestem>"
    <stem du obl> == "<middlestem>"
    <stem pl obl gen> == "<weakeststem>"
    <stem du obl gen> == "<weakeststem>"
    <masc stem sg dir acc> == "<strongstem>"
    <stem du dir> == "<strongstem>"
    <stem pl dir nom> == "<strongstem>"
    <$gender stem sg dir voc> == "<gunastem>".

N_STEM:
    <> == DERC_STEM
    <stemres> == n
    <middlestem> == <astem>
    <neut stem> == "<weakeststem>"
    <neut stem pl dir> == "<strongstem>".

R_STEM:
    <> == DERC_STEM
    <stemres> == r
    <stem sg obl> == <weakeststem>
    <stem du obl> == <weakeststem>
    <stem sg obl gen> == <ustem>
    <suff sg obl gen> == r
    <vstem pl> == <weakeststem>
    <stem pl> == V_STEM
    <stem pl dir nom> == DERC_STEM
    <suff pl> == V_STEM.

IN_STEM:
    <> == N_STEM
    <vstem> == <istem>
    <strongstem> == <nstem>
    <middlestem> == <vstem>
    <weakeststem> == <strongstem>
    <$gender stem sg dir voc> == <strongstem>.

NT_STEM:
    <> == N_STEM
    <stemobs> == t
    <masc stem sg dir nom> == <longnstem>
    <strongstem> == ALL_STEM 
    <middlestem> == <vstem> <stemobs>
    <weakeststem> == <middlestem>.

Loka:
    <meaning> == world
    <> == NONPRON_A_STEM
    <gen> == masc
    <root> == l o k.

Dharma:
    <meaning> == law
    <> == NONPRON_A_STEM
    <gen> == masc
    <root> == dh a r m.

Ruupa:
    <meaning> == form
    <> == NONPRON_A_STEM
    <gen> == neut
    <root> == r u u p.

Kanyaa:
    <meaning> == girl
    <> == AA_STEM
    <root> == k a n y a.

PaaNi:
    <meaning> == hand
    <> == I_STEM
    <gen> == masc
    <root> == p a a N.

Jaati:
    <meaning> == birth
    <> == I_STEM
    <gen> == fem
    <root> == j a a t.


Vaari:
    <meaning> == water
    <> == I_STEM
    <gen> == neut
    <root> == v a a r.

Nadii:
    <meaning> == river
    <> == II_STEM
    <root> == n a d.

Dhii:
    <meaning> == thought
    <> == MS_STEM
    <gen> == fem
    <root> == dh i y.


BhikShu:
    <meaning> == monk
    <> == U_STEM
    <gen> == masc
    <root> == bh i k Sh.


Dhenu:
    <meaning> == cow
    <> == U_STEM
    <gen> == fem
    <root> == dh e n.

Madhu:
    <meaning> == honey
    <> == U_STEM
    <gen> == neut
    <root> == m a dh.

Vadhuu:
    <meaning> == bride
    <> == UU_STEM
    <root> == v a dh.

Bhuu:
    <meaning> == earth
    <> == MS_STEM
    <gen> == fem
    <root> == bh u v.


Shaastar:
    <meaning> == teacher
    <> == R_STEM
    <gen> == masc
    <root> == sh a a s t.


Marut:
    <meaning> == wind
    <> == C_STEM
    <gen> == masc
    <root> == m a r
    <vstem> == <ustem>
    <stemobs> == t.

Jagat:
    <meaning> == world
    <> == C_STEM
    <gen> == neut
    <root> == j a g
    <longvstem> == <vstem>
    <stemobs> == t.

Shiilavant:
    <meaning> == virtuous
    <> == NT_STEM
    <root> == sh i i l a v.

Shiilavant_M:
    <> == Shiilavant
    <gen> == masc.

Shiilavant_F:
    <meaning> == Shiilavant
    <> == II_STEM
    <gen> == fem
    <root> == "Shiilavant:<weakeststem>".

Shiilavant_N:
    <> == Shiilavant
    <gen> == neut.




Aatman:
    <meaning> == self, soul
    <> == N_STEM
    <gen> == masc
    <root> == a a t m
    <weakeststem> == <gunastem>.

Raajan:
    <meaning> == king
    <> == N_STEM
    <gen> == masc
    <root> == r a a j.

Naaman:
    <meaning> == name
    <> == N_STEM
    <gen> == neut
    <root> == n a a m.

Hastin:
    <meaning> == elephant
    <> == IN_STEM
    <gen> == masc
    <root> == h a s t.
 


Manas:
    <meaning> == mind
    <> == C_STEM
    <gen> == neut
    <root> == m a n
    <stemobs> == s.



Vaach:
    <meaning> == speech
    <> == C_STEM
    <gen> == fem
    <root> == v a
    <vstem> == <astem>
    <stemobs> == ch.



Dish:
    <meaning> == region
    <> == C_STEM
    <gen> == fem
    <root> == d
    <vstem> == <istem>
    <stemobs> == sh.

Ta:
    <meaning> == demonstrative pronoun
    <> == PRON_A_STEM
    <root> == t
    <root sg dir nom> == s.


Ta_M:
    <> == Ta
    <gen> == masc.

Ta_F:
    <meaning> == Ta
    <$number dir voc> == Ta
    <> == AA_STEM
    <root> == Ta a
    <stem sg obl> == <root> s y a
    <stem sg obl ins> == AA_STEM   
    <stem pl obl gen> == PRON_A_STEM
    <gen> == fem.

Ta_N:
    <> == Ta
    <root sg> == Ta:<root>
    <gen> == neut.

#hide SANDHI ALL_STEM V_STEM IU_STEM VV_STEM VV_STEM2 II_STEM
UU_STEM MS_STEM A_STEM AA_STEM I_STEM NT_STEM U_STEM DERC_STEM
C_STEM N_STEM IN_STEM PRON_A_STEM NONPRON_A_STEM NR_STEM R_STEM
Shiilavant Ta.

#show <meaning>
      <gen>
      <sg dir nom> <du dir nom> <pl dir nom>
      <sg dir acc> <du dir acc> <pl dir acc>
      <sg obl ins> <du obl ins> <pl obl ins>
      <sg obl dat> <du obl dat> <pl obl dat>
      <sg obl abl> <du obl abl> <pl obl abl>
      <sg obl gen> <du obl gen> <pl obl gen>
      <sg obl loc> <du obl loc> <pl obl loc>
      <sg dir voc> <du dir voc> <pl dir voc>.